OBJECT Codeunit 60000 Offline Count Extensions
{
  OBJECT-PROPERTIES
  {
    Date=02/25/19;
    Time=[ 3:43:55 PM];
    Modified=Yes;
    Version List=;
  }
  PROPERTIES
  {
    TableNo=23044511;
    OnRun=BEGIN
            trecEventParams.COPY(Rec, TRUE);

            CASE getExtensibilityEvent OF
              "Extensibility Event"::OnPrint: onPrint;
              "Extensibility Event"::OnBeforeProcessEvent: onBeforeProcessEvent;
              "Extensibility Event"::OnAfterProcessEvent:  onAfterProcessEvent;
            END;

            COPY(trecEventParams, TRUE);
          END;

  }
  CODE
  {
    VAR
      trecEventParams@1000000000 : TEMPORARY Record 23044511;
      cuWMDMCommon@1000000001 : Codeunit 23044501;
      cuWMDMDataset@1000000002 : Codeunit 23044535;

    LOCAL PROCEDURE onPrint@1000000001();
    BEGIN
      CASE trecEventParams.getEvent OF
      END;
    END;

    LOCAL PROCEDURE onBeforeProcessEvent@1000000002();
    BEGIN

      CASE trecEventParams.getEvent OF
        2000000: ProcessSimpleCountEntries();
      END;
    END;

    LOCAL PROCEDURE onAfterProcessEvent@1000000003();
    BEGIN

      CASE trecEventParams.getEvent OF

      END;
    END;

    LOCAL PROCEDURE sendSuccessResult@1000000014(psResultMessage@1000000001 : Text;pbOverrideEvent@1000000002 : Boolean);
    VAR
      lcuWMDMCommon@1000000003 : Codeunit 23044501;
      lbtTemp@1000000004 : BigText;
      losTemp@1000000005 : OutStream;
    BEGIN
      lcuWMDMCommon.generateSuccessReturnWithMsg(1, psResultMessage,lbtTemp);
      trecEventParams.setExtensibilityOverrideWMDM(pbOverrideEvent);
      trecEventParams."Extensibility Blob".CREATEOUTSTREAM( losTemp );
      lbtTemp.WRITE( losTemp );
      trecEventParams.MODIFY();
    END;

    LOCAL PROCEDURE sendStandardResult@1000000009(pbtResult@1000000001 : BigText;pbOverrideEvent@1000000000 : Boolean);
    VAR
      losTemp@1000000003 : OutStream;
    BEGIN
      trecEventParams.setExtensibilityOverrideWMDM(pbOverrideEvent);
      trecEventParams."Extensibility Blob".CREATEOUTSTREAM( losTemp );
      pbtResult.WRITE( losTemp );
      trecEventParams.MODIFY();
    END;

    PROCEDURE ProcessSimpleCountEntries@1000000000();
    VAR
      lrecCountSheetLine@1000000001 : Record 23044301;
      lrecPDAConfig@1000000005 : Record 23044504;
      lcuInvCountMgmt@1000000003 : Codeunit 23044507;
      lcuWMDMCommon@1000000004 : Codeunit 23044501;
      lcodCountNo@1000000002 : Code[20];
      liCount@1000000000 : Integer;
      liIndex@1000000006 : Integer;
    BEGIN
      cuWMDMCommon.getPDAConfig(lrecPDAConfig,trecEventParams);
      lcodCountNo := lcuInvCountMgmt.getActiveCountBySheet('', lrecPDAConfig."Location Code");

      liCount := trecEventParams.getValueAsInt('count');
      FOR liIndex:=0 TO (liCount-1) DO BEGIN
        CLEAR(lrecCountSheetLine);
        lrecCountSheetLine.INIT;
        lrecCountSheetLine.VALIDATE("Count No.",lcodCountNo);
        lrecCountSheetLine.VALIDATE("Sheet Name", trecEventParams.getValue(STRSUBSTNO('entry_%1_%2',liIndex,'SheetName')));
        lrecCountSheetLine.VALIDATE("Item No.", trecEventParams.getValue(STRSUBSTNO('entry_%1_%2',liIndex,'ItemNumber')));
        lrecCountSheetLine.VALIDATE("Location Code",lrecPDAConfig."Location Code");
        lrecCountSheetLine.VALIDATE("Bin Code", trecEventParams.getValue(STRSUBSTNO('entry_%1_%2',liIndex,'BinCode')));
        lrecCountSheetLine.VALIDATE(Quantity, trecEventParams.getValueAsDecimal(STRSUBSTNO('entry_%1_%2',liIndex,'Quantity')));

        IF trecEventParams.getValueAsInt(STRSUBSTNO('entry_%1_%2',liIndex,'UOM')) = 0 THEN
          lrecCountSheetLine.VALIDATE("Unit of Measure Code", 'PCS')
        ELSE
          lrecCountSheetLine.VALIDATE("Unit of Measure Code", 'BOX');

        lrecCountSheetLine.INSERT(TRUE);
      END;

      sendSuccessResult('',TRUE);
    END;

    BEGIN
    END.
  }
}

